FJ Software Foren-Übersicht  
 Homepage   •  Suchen   •  FAQ   •  Mitgliederliste   •  Registrieren   •  Login
 SMS aus CVS oder Textdatei erstellen Nächstes Thema anzeigen
Vorheriges Thema anzeigen
Neues Thema eröffnenNeue Antwort erstellen
Autor Nachricht
Peter-Müller



Anmeldedatum: 13.04.2020
Beiträge: 5
Wohnort: Nordsee

BeitragVerfasst am: Mo Apr 13, 2020 06:56 Antworten mit ZitatNach oben

Hallo zusammen,
ich würde gerne eine CVS Tabelle oder eine Textdatei mit Telefonnummer und einem Text erstellen, den ich dann per Handy als SMS versenden kann. Also keine Spam sondern ca. 30 SMS als Terminbestätigungen für die nächste Woche so das ich den Text auch mit persönlicher Anrede, Datum und Uhrzeit versenden kann.
Gibt es diese Möglichkeit schon im MPE?
Benutzer-Profile anzeigenPrivate Nachricht senden
icke1954
Moderator


Anmeldedatum: 19.04.2014
Beiträge: 11548

BeitragVerfasst am: Mo Apr 13, 2020 21:13 Antworten mit ZitatNach oben

Willkommen in unserem Forum!
Siehe => http://www.fjsoft.at/forum/viewtopic.php?p=113811#113811

_________________
Samsung Galaxy S3 / Android 4.3
Samsung Galaxy S5 / Android 6.01
Samsung Galaxy S8 / Android 9.0
Samsung Galaxy Tab 4 Android 9.0
MPE Version 1.8.15 akt. Nightly / akt. MPE-Client
W7 64Bit / Outlook 2010 32 Bit
Benutzer-Profile anzeigenPrivate Nachricht sendenE-Mail senden
Peter-Müller



Anmeldedatum: 13.04.2020
Beiträge: 5
Wohnort: Nordsee

BeitragVerfasst am: Di Apr 14, 2020 21:03 Antworten mit ZitatNach oben

Oh super!

DANKE Icke1954!

Die beiden Dateien kann ich erstellen.

Aber... Ich habe leider keine Ahnung vom Programmieren. Embarassed

Nun zu meinen Problemen:
1. Ich möchte nicht immer den einen Text zu allen senden, sondern eine Terminbestätigungen senden. Eine Bestätigung am 15.04. um 10:00 Uhr und dem nächsten um 11.00 Uhr und den nächsten z.B. um 13.00Uhr. Ausserdem würde ich gerne eine persönliche Anrede mit einbauen in die Textdatei. Gibt es dafür eine Vorlage mit anderem Quellcode für die VBS-Datei? Wenn ich es richtig verstehe, wird ja jedem nach der Zeile 1 die Zeile 1 zugesendet oder?

Ich stelle mir es so vor, dass ein der einen Spalte die Telefonnummer steht und in der nächsten dann der Text in der jeweiligen Zeile. Vielleicht gibt es hier aber auch noch bessere Ideen?

2. Gibt es hier noch eine Anleitung, was ich genau zu tun habe, wenn ich die txt Datei und die VBS-Datei erstellt habe?

VG Peter
Benutzer-Profile anzeigenPrivate Nachricht senden
Peter-Müller



Anmeldedatum: 13.04.2020
Beiträge: 5
Wohnort: Nordsee

BeitragVerfasst am: Di Apr 14, 2020 21:19 Antworten mit ZitatNach oben

Oh, sehr cool!

Meine 2 Frage hat sich bereits erledigt... FREU!
Benutzer-Profile anzeigenPrivate Nachricht senden
icke1954
Moderator


Anmeldedatum: 19.04.2014
Beiträge: 11548

BeitragVerfasst am: Mi Apr 15, 2020 00:16 Antworten mit ZitatNach oben

Zu 1.
Erstelle eine Textdatei => SMS.txt:
1. Zeile: HandyNr-1;SMS-Text-1
2. Zeile: HandyNr-2;SMS-Text-2
3. Zeile: HandyNr-3;SMS-Text-3
...

Erstelle eine VBS-Datei mit folgendem Inhalt:
Code:
Dim TelNr()
Dim SMSText()
dateiPfad = "SMS.txt"
x = 0
Const ForReading = 1

Set fs = CreateObject("Scripting.FileSystemObject")

If (fs.FileExists(dateiPfad)) Then
   Set f = fs.OpenTextFile(dateiPfad, ForReading)

   Do While f.AtEndOfStream <> True
      x = x+1
      ReDim Preserve TelNr(x)
      ReDim Preserve SMSText(x)
      org_zeile = f.Readline
      TelNr(x)=left (org_zeile, instr(org_zeile, ";")-1)
      SMSText(x)=right (org_zeile, len(org_zeile)-instrrev (org_zeile, ";"))
   Loop
   f.Close
   AnzahlSMS = x
end if

For n = 1 to AnzahlSMS
   RunMPE "action=sendmessage flags=noerrmsg savetosent=1 number=" & TelNr(n) & " text=" & Chr(34) & SMSText(n) & Chr(34)
   WScript.Sleep 5000

next

Function RunMPE(Arguments)
  set shell = CreateObject("WScript.Shell")
  shell.run "myphoneexplorer " & Arguments ,3
End Function


oder

Erstelle eine Textdatei => SMS.txt:
1. Zeile: SMS-Text-1
2. Zeile: HandyNr-1
3. Zeile: SMS-Text-2
4. Zeile: HandyNr-2
5. Zeile: SMS-Text-3
6. Zeile: HandyNr-3
....


Erstelle eine VBS-Datei mit folgendem Inhalt:
Code:

Dim TelNr()
Dim SMSText()
dateiPfad = "SMS.txt"
x = 0
Const ForReading = 1

Set fs = CreateObject("Scripting.FileSystemObject")

If (fs.FileExists(dateiPfad)) Then
   Set f = fs.OpenTextFile(dateiPfad, ForReading)

   Do While f.AtEndOfStream <> True
      x = x+1
      ReDim Preserve TelNr(x)
      ReDim Preserve SMSText(x)
      org_zeile = f.Readline
      if x mod 2 = 1 then
         x2=(x+1)-(x+1)/2
         SMSText(x2)= org_zeile
      else
         TelNr(x-x/2)= org_zeile
      end if
   Loop
   f.Close
   AnzahlSMS = x/2
end if

For n = 1 to AnzahlSMS
   RunMPE "action=sendmessage flags=noerrmsg savetosent=1 number=" & TelNr(n) & " text=" & Chr(34) & SMSText(n) & Chr(34)
   WScript.Sleep 10000
next

Function RunMPE(Arguments)
  set shell = CreateObject("WScript.Shell")
  shell.run "myphoneexplorer " & Arguments ,3
End Function

_________________
Samsung Galaxy S3 / Android 4.3
Samsung Galaxy S5 / Android 6.01
Samsung Galaxy S8 / Android 9.0
Samsung Galaxy Tab 4 Android 9.0
MPE Version 1.8.15 akt. Nightly / akt. MPE-Client
W7 64Bit / Outlook 2010 32 Bit
Benutzer-Profile anzeigenPrivate Nachricht sendenE-Mail senden
Peter-Müller



Anmeldedatum: 13.04.2020
Beiträge: 5
Wohnort: Nordsee

BeitragVerfasst am: Mi Apr 15, 2020 10:58 Antworten mit ZitatNach oben

Vielen Dank Icke1954!

Ich werde dein Script am Abend ausprobieren.

Very Happy

VG Peter
Benutzer-Profile anzeigenPrivate Nachricht senden
Peter-Müller



Anmeldedatum: 13.04.2020
Beiträge: 5
Wohnort: Nordsee

BeitragVerfasst am: Sa Apr 18, 2020 10:41 Antworten mit ZitatNach oben

Hallo Icke1954,

ich habe gerade Dein Skript ausprobiert, leider habe ich eine Fehlermeldung in Zeile: 17, Zeichen: 7, Fehler: ungültige Prozeduraufruf "left" Code: 800A0005.

Würdest Du nochmal über den Code schauen?

Nochmal Danke für das Script und

VG Peter
Benutzer-Profile anzeigenPrivate Nachricht senden
icke1954
Moderator


Anmeldedatum: 19.04.2014
Beiträge: 11548

BeitragVerfasst am: Sa Apr 18, 2020 13:47 Antworten mit ZitatNach oben

Bitte überprüfe Deine Textdatei SMS.txt
- Es darf keine Leerzeilen geben
- Achte auf folgendes Format:
[Telefonnummer][Semikolon][SMS-Text]

Ich habe den Code etwas angepasst, um diese Probleme abzufangen:

Code:
Dim TelNr()
Dim SMSText()
dateiPfad = "SMS.txt"
x = 0
Const ForReading = 1

Set fs = CreateObject("Scripting.FileSystemObject")

If (fs.FileExists(dateiPfad)) Then
   Set f = fs.OpenTextFile(dateiPfad, ForReading)

   Do While f.AtEndOfStream <> True
      x = x+1
      ReDim Preserve TelNr(x)
      ReDim Preserve SMSText(x)
      org_zeile = f.Readline
      if not instr(org_zeile, ";")=0 then
        TelNr(x)=left (org_zeile, instr(org_zeile, ";")-1)
        SMSText(x)=right (org_zeile, len(org_zeile)-instrrev (org_zeile, ";"))
      else x = x-1
      end if
   Loop
   f.Close
   AnzahlSMS = x
end if

For n = 1 to AnzahlSMS
   RunMPE "action=sendmessage flags=noerrmsg savetosent=1 number=" & TelNr(n) & " text=" & Chr(34) & SMSText(n) & Chr(34)
   WScript.Sleep 5000

next

Function RunMPE(Arguments)
  set shell = CreateObject("WScript.Shell")
  shell.run "myphoneexplorer " & Arguments ,3
End Function

_________________
Samsung Galaxy S3 / Android 4.3
Samsung Galaxy S5 / Android 6.01
Samsung Galaxy S8 / Android 9.0
Samsung Galaxy Tab 4 Android 9.0
MPE Version 1.8.15 akt. Nightly / akt. MPE-Client
W7 64Bit / Outlook 2010 32 Bit
Benutzer-Profile anzeigenPrivate Nachricht sendenE-Mail senden
Beiträge der letzten Zeit anzeigen:      
Neues Thema eröffnenNeue Antwort erstellen


 Gehe zu:   



Nächstes Thema anzeigen
Vorheriges Thema anzeigen
Du kannst keine Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum nicht antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.

Powered by phpBB © 2001, 2002 phpBB Group :: FI Theme :: Alle Zeiten sind GMT + 1 Stunde
Deutsche Übersetzung von phpBB.de